forked from AkkomaGang/akkoma
58a4f350a8
This patch refactors gun pooling to use Elixir process registry and simplifies adapter option insertion. Having the pool use process registry instead of a GenServer has a number of advantages: - Simpler code: the initial implementation adds about half the lines of code it deletes - Concurrency: unlike a GenServer, ETS-based registry can handle multiple checkout/checkin requests at the same time - Precise and easy idle connection clousure: current proposal for closing idle connections in the GenServer-based pool needs to filter through all connections once a minute and compare their last active time with closing time. With Elixir process registry this can be done by just using `Process.send_after`/`Process.cancel_timer` in the worker process. - Lower memory footprint: In my tests `gun-memory-leak` branch uses about 290mb on peak load (250 connections) and 235mb on idle (5-10 connections). Registry-based pool uses 210mb on idle and 240mb on peak load
62 lines
1.6 KiB
Elixir
62 lines
1.6 KiB
Elixir
# Pleroma: A lightweight social networking server
|
|
# Copyright © 2017-2020 Pleroma Authors <https://pleroma.social/>
|
|
# SPDX-License-Identifier: AGPL-3.0-only
|
|
|
|
defmodule Pleroma.HTTP.AdapterHelper.Gun do
|
|
@behaviour Pleroma.HTTP.AdapterHelper
|
|
|
|
alias Pleroma.Gun.ConnectionPool
|
|
alias Pleroma.HTTP.AdapterHelper
|
|
|
|
require Logger
|
|
|
|
@defaults [
|
|
connect_timeout: 5_000,
|
|
domain_lookup_timeout: 5_000,
|
|
tls_handshake_timeout: 5_000,
|
|
retry: 1,
|
|
retry_timeout: 1000,
|
|
await_up_timeout: 5_000
|
|
]
|
|
|
|
@spec options(keyword(), URI.t()) :: keyword()
|
|
def options(incoming_opts \\ [], %URI{} = uri) do
|
|
proxy =
|
|
Pleroma.Config.get([:http, :proxy_url])
|
|
|> AdapterHelper.format_proxy()
|
|
|
|
config_opts = Pleroma.Config.get([:http, :adapter], [])
|
|
|
|
@defaults
|
|
|> Keyword.merge(config_opts)
|
|
|> add_scheme_opts(uri)
|
|
|> AdapterHelper.maybe_add_proxy(proxy)
|
|
|> Keyword.merge(incoming_opts)
|
|
end
|
|
|
|
@spec after_request(keyword()) :: :ok
|
|
def after_request(opts) do
|
|
if opts[:conn] && opts[:body_as] != :chunks do
|
|
ConnectionPool.release_conn(opts[:conn])
|
|
end
|
|
|
|
:ok
|
|
end
|
|
|
|
defp add_scheme_opts(opts, %{scheme: "http"}), do: opts
|
|
|
|
defp add_scheme_opts(opts, %{scheme: "https"}) do
|
|
opts
|
|
|> Keyword.put(:certificates_verification, true)
|
|
|> Keyword.put(:tls_opts, log_level: :warning)
|
|
end
|
|
|
|
@spec get_conn(URI.t(), keyword()) :: {:ok, keyword()} | {:error, atom()}
|
|
def get_conn(uri, opts) do
|
|
case ConnectionPool.get_conn(uri, opts) do
|
|
{:ok, conn_pid} -> {:ok, Keyword.merge(opts, conn: conn_pid, close_conn: false)}
|
|
err -> err
|
|
end
|
|
end
|
|
end
|