lib/pleroma/emoji.ex

@@ -9,6 +9,7 @@ defmodule Pleroma.Emoji do
   """
   use GenServer
 
+  alias Pleroma.Emoji.Combinations
   alias Pleroma.Emoji.Loader
 
   require Logger
@@ -186,4 +187,17 @@ def emoji_url(%{"type" => "EmojiReact", "content" => emoji, "tag" => tags}) do
   end
 
   def emoji_url(_), do: nil
+
+  emoji_qualification_map =
+    emojis
+    |> Enum.filter(&String.contains?(&1, "\uFE0F"))
+    |> Combinations.variate_emoji_qualification()
+
+  for {qualified, unqualified_list} <- emoji_qualification_map do
+    for unqualified <- unqualified_list do
+      def fully_qualify_emoji(unquote(unqualified)), do: unquote(qualified)
+    end
+  end
+
+  def fully_qualify_emoji(emoji), do: emoji
 end

lib/pleroma/emoji/combinations.ex

@@ -0,0 +1,45 @@
+# Pleroma: A lightweight social networking server
+# Copyright © 2017-2022 Pleroma Authors <https://pleroma.social/>
+# SPDX-License-Identifier: AGPL-3.0-only
+
+defmodule Pleroma.Emoji.Combinations do
+  # FE0F is the emoji variation sequence. It is used for fully-qualifying
+  # emoji, and that includes emoji combinations.
+  # This code generates combinations per emoji: for each FE0F, all possible
+  # combinations of the character being removed or staying will be generated.
+  # This is made as an attempt to find all partially-qualified and unqualified
+  # versions of a fully-qualified emoji.
+  # I have found *no cases* for which this would be a problem, after browsing
+  # the entire emoji list in emoji-test.txt. This is safe, and, sadly, most
+  # likely sane too.
+
+  defp qualification_combinations(codepoints) do
+    qualification_combinations([[]], codepoints)
+  end
+
+  defp qualification_combinations(acc, []), do: acc
+
+  defp qualification_combinations(acc, ["\uFE0F" | tail]) do
+    acc
+    |> Enum.flat_map(fn x -> [x, x ++ ["\uFE0F"]] end)
+    |> qualification_combinations(tail)
+  end
+
+  defp qualification_combinations(acc, [codepoint | tail]) do
+    acc
+    |> Enum.map(&Kernel.++(&1, [codepoint]))
+    |> qualification_combinations(tail)
+  end
+
+  def variate_emoji_qualification(emoji) when is_binary(emoji) do
+    emoji
+    |> String.codepoints()
+    |> qualification_combinations()
+    |> Enum.map(&List.to_string/1)
+  end
+
+  def variate_emoji_qualification(emoji) when is_list(emoji) do
+    emoji
+    |> Enum.map(fn emoji -> {emoji, variate_emoji_qualification(emoji)} end)
+  end
+end

lib/pleroma/web/activity_pub/object_validators/emoji_react_validator.ex

@@ -79,8 +79,7 @@ defp matches_shortcode?(nil), do: false
   defp matches_shortcode?(s), do: Regex.match?(@emoji_regex, s)
 
   defp fix_emoji_qualification(%{"content" => emoji} = data) do
-    # Emoji variation sequence
-    new_emoji = emoji <> "\uFE0F"
+    new_emoji = Pleroma.Emoji.fully_qualify_emoji(emoji)
 
     cond do
       Pleroma.Emoji.is_unicode_emoji?(emoji) ->

test/fixtures/emoji-reaction-unqualified.json

@@ -1,30 +0,0 @@
-{
-  "type": "EmojiReact",
-  "signature": {
-    "type": "RsaSignature2017",
-    "signatureValue": "fdxMfQSMwbC6wP6sh6neS/vM5879K67yQkHTbiT5Npr5wAac0y6+o3Ij+41tN3rL6wfuGTosSBTHOtta6R4GCOOhCaCSLMZKypnp1VltCzLDoyrZELnYQIC8gpUXVmIycZbREk22qWUe/w7DAFaKK4UscBlHDzeDVcA0K3Se5Sluqi9/Zh+ldAnEzj/rSEPDjrtvf5wGNf3fHxbKSRKFt90JvKK6hS+vxKUhlRFDf6/SMETw+EhwJSNW4d10yMUakqUWsFv4Acq5LW7l+HpYMvlYY1FZhNde1+uonnCyuQDyvzkff8zwtEJmAXC4RivO/VVLa17SmqheJZfI8oluVg==",
-    "creator": "http://mastodon.example.org/users/admin#main-key",
-    "created": "2018-02-17T18:57:49Z"
-  },
-  "object": "http://localtesting.pleroma.lol/objects/eb92579d-3417-42a8-8652-2492c2d4f454",
-  "content": "❤",
-  "nickname": "lain",
-  "id": "http://mastodon.example.org/users/admin#reactions/2",
-  "actor": "http://mastodon.example.org/users/admin",
-  "@context": [
-    "https://www.w3.org/ns/activitystreams",
-    "https://w3id.org/security/v1",
-    {
-      "toot": "http://joinmastodon.org/ns#",
-      "sensitive": "as:sensitive",
-      "ostatus": "http://ostatus.org#",
-      "movedTo": "as:movedTo",
-      "manuallyApprovesFollowers": "as:manuallyApprovesFollowers",
-      "inReplyToAtomUri": "ostatus:inReplyToAtomUri",
-      "conversation": "ostatus:conversation",
-      "atomUri": "ostatus:atomUri",
-      "Hashtag": "as:Hashtag",
-      "Emoji": "toot:Emoji"
-    }
-  ]
-}

test/pleroma/web/activity_pub/transmogrifier/emoji_react_handling_test.exs

@@ -91,11 +91,15 @@ test "it works for incoming unqualified emoji reactions" do
     other_user = insert(:user, local: false)
     {:ok, activity} = CommonAPI.post(user, %{status: "hello"})
 
+    # woman detective emoji, unqualified
+    unqualified_emoji = [0x1F575, 0x200D, 0x2640] |> List.to_string()
+
     data =
-      File.read!("test/fixtures/emoji-reaction-unqualified.json")
+      File.read!("test/fixtures/emoji-reaction.json")
       |> Jason.decode!()
       |> Map.put("object", activity.data["object"])
       |> Map.put("actor", other_user.ap_id)
+      |> Map.put("content", unqualified_emoji)
 
     {:ok, %Activity{data: data, local: false}} = Transmogrifier.handle_incoming(data)
 
@@ -103,13 +107,14 @@ test "it works for incoming unqualified emoji reactions" do
     assert data["type"] == "EmojiReact"
     assert data["id"] == "http://mastodon.example.org/users/admin#reactions/2"
     assert data["object"] == activity.data["object"]
-    # heart emoji with added emoji variation sequence
-    assert data["content"] == "❤\uFE0F"
+    # woman detective emoji, fully qualified
+    emoji = [0x1F575, 0xFE0F, 0x200D, 0x2640, 0xFE0F] |> List.to_string()
+    assert data["content"] == emoji
 
     object = Object.get_by_ap_id(data["object"])
 
     assert object.data["reaction_count"] == 1
-    assert match?([["❤\uFE0F", _]], object.data["reactions"])
+    assert match?([[emoji, _]], object.data["reactions"])
   end
 
   test "it reject invalid emoji reactions" do